[Database-Tự Học SQL] COM2034_SQL Server - Lab 4: Điều Kiện & Vòng Lặp - P3 TRANSACTION (Transact-SQL)

LÝ THUYẾT:

TRANSACTION: là việc thực hiện một nhóm các câu lệnh, các câu lệnh này được thực thi một cách tuần tự và độc lập nhau. Nếu tất cả câc lệnh trong nhóm thực hiện thành công khi đó tất cả các sự thay đổi dữ liệu được thực hiện trong Transaction được lưu vào cơ sở dữ liệu (COMMIT). Tuy nhiên, nếu có một trong các lệnh của nhóm lệnh thực thi thất bại thì toàn bộ tiến trình sẽ thất bại, đồng nghĩa với việc dữ liệu phải ROLLBACK về trạng thái ban đầu.

Các tiêu chuẩn Transaction:

• Bảo toàn (Atomicity) - đảm bảo rằng tất cả các câu lệnh trong nhóm lệnh được thực thi thành công. Nếu không, transaction bị hủy bỏ tại thời điểm thất bại và tất cả các thao tác trước đó được khôi phục về trạng thái cũ.
• Nhất quán (Consistency) - đảm bảo rằng cơ sở dữ liệu thay đổi chính xác các trạng thái khi một transaction được thực thi thành công.
• Độc lập (Isolation) - cho phép các transaction hoạt động độc lập và minh bạch với nhau.
• Bền bỉ (Durability) - đảm bảo rằng kết quả của một transaction được commit vẫn tồn tại trong trường hợp lỗi hệ thống.

Transaction T-SQL tường minh có dạng (code mẫu đơn giản)

SET XACT_ABORT ON

BEGIN TRAN

BEGIN TRY
	--  Lệnh 1
	--  Lệnh 2
	--  Lệnh ...
 
COMMIT
END TRY
 
BEGIN CATCH
 
  ROLLBACK
 
END CATCH

Ý nghĩa các lệnh dùng để xử lý transaction.

• COMMIT - để lưu các thay đổi.
• ROLLBACK - để khôi phục lại các thay đổi.
• SAVEPOINT - tạo ra các điểm trong transaction để ROLLBACK.
• SET TRANSACTION - thiết lập các thuộc tính cho transaction.

Các lệnh điều khiển transaction chỉ được sử dụng với các lệnh thao tác dữ liệu DML như - INSERT, UPDATE và DELETE.

Noted: Chúng không thể được sử dụng trong lệnh CREATE TABLE hoặc DROP TABLE vì các hoạt động này được tự động được commit trong cơ sở dữ liệu.

Giao dịch lồng (nested transaction) là giao dịch được viết bên trong một giao dịch khác.

• Mỗi khi câu lệnh BEGIN TRAN được thực thi, hàm hệ thống @@TRANCOUNT được tăng thêm 1. 
• Khi thực thi câu lệnh COMMIT TRAN.
• Nếu @@TRANCOUNT > 1, các thay đổi sẽ không được commit. Thay vào đó @@TRANCOUNT giảm đi 1.
• Nếu @@TRANCOUNT = 1, mọi thay đổi đã được thực hiện trên CSDL trong suốt giao dịch sẽ được commit và @@TRANCOUNT được gán bằng 0. 
• Câu lệnh ROLLBACK TRAN roll-back toàn bộ các giao dịch đang hoạt động và thiết lập giá trị cho @@TRANCOUNT về 0

YÊU CẦU:

Bài 1: (Mục đích là làm quen với Transaction)

• Hiển thị mã phòng ban bằng 2, hiển thị Transaction count
• Thực hiện đổi tên (TENPHG) thành 'Phong KT 004'
• Thực hiện Rollback lại tên ban đầu (lúc chưa update ...set....)

Bài 2:

Yêu cầu sử dụng giao dịch kết hợp với try catch để chặn lỗi thực hiện 2 yêu cầu sau:

• Viết chương trình thêm một nhân viên mới. Nếu thêm nhân viên thành công thì thêm 1 thân nhân cho nhân viên vừa tạo.
• Viết chương trình thêm một công việc mới cho đề án số 1, đồng thời phân công nhân viên mói thêm ở câu trên đảm nhận công việc mới tạo.

THỰC HIỆN:

Bài 1:

• Hiển thị mã phòng ban bằng 2, hiển thị Transaction count
• Thực hiện đổi tên (TENPHG) thành 'Phong KT 004'
• Thực hiện Rollback lại tên ban đầu (lúc chưa update ...set....)

Code:

-- ban đầu chưa thay đổi (1)
SELECT * FROM PHONGBAN WHERE PHONGBAN.MAPHG = 2
SELECT @@TRANCOUNT AS dem_Tran

-- thực hiện sửa TENPHG thành 'Phong KT 004' (2)
BEGIN TRAN
	  UPDATE PHONGBAN
	  SET TENPHG = 'Phong KT 004'
	  WHERE MAPHG = 2

--COMMIT TRAN -- Sau khi commit, TRANCOUNT sẽ  = 0
SELECT * FROM PHONGBAN WHERE PHONGBAN.MAPHG = 2 -- kiểm sau khi thực hiện lệnh update... set..
SELECT @@TRANCOUNT AS dem_Tran -- kiểm tra biến đếm 

-- thực hiện Rollback và kiểm tra kết quả (3)
ROLLBACK TRAN -- RollBack thành không khi TRANCOUNT > 0 
SELECT * FROM PHONGBAN WHERE PHONGBAN.MAPHG = 2
SELECT @@TRANCOUNT AS dem_Tran

Kết quả:

• (1) Ban đầu TRANCOUNT = 0
• (2) Khi thực hiện thay đổi tên TRANCOUNT tăng lên 1 đơn vị
• (3) Thực hiện Rollback thì TRANCOUNT sẽ thiết lập giá trị là 0

Bài 2:

Yêu cầu sử dụng giao dịch kết hợp với try catch để chặn lỗi thực hiện 2 yêu cầu sau:

• Viết chương trình thêm một nhân viên mới. Nếu thêm nhân viên thành công thì thêm 1 thân nhân cho nhân viên vừa tạo.

Code mẫu đơn giản:

DECLARE @ma_nv NVARCHAR(9) = '2222'
SET XACT_ABORT ON

BEGIN TRAN

BEGIN TRY
	INSERT INTO NHANVIEN ( [HONV] ,[TENLOT] ,[TENNV] ,[MANV] ,[NGSINH] ,[DCHI] ,[PHAI] ,[LUONG] ,[MA_NQL] ,[PHG] )
					VALUES ('Van', 'Cong',  'Khanh',  @ma_nv, '2000/10/10','Binh Duong','Nam',30000,'005', 5)
	INSERT INTO THANNHAN ([MA_NVIEN] ,[TENTN],[PHAI],[NGSINH] ,[QUANHE]	)
					VALUES (@ma_nv, 'Nhan Nhan', 'Nam','2000/10/10','ban be') -- sửa @ma_nv thành 99999
	PRINT 'Them THANH CONG'

COMMIT -- thực hiện lưu nếu cả 2 dòng lệnh thêm thành công

END TRY
 
BEGIN CATCH
 
  ROLLBACK -- Nếu 1 trong 2 lệnh INSERT không thành công sẽ thông báo lỗi
  PRINT 'Them THAT BAI'
 
END CATCH

Noted: Với code trên khi thêm nhân viên mới chúng ta cần thay dòng thứ 1 là được, tuy nhiên để kiểm tra ROLLBACK thi chúng ta cố tình sửa dòng INTSERT trong bảng thân sai đi để kiểm tra. Ví dụ: thay đổi @ma_nv thành '99999' (dòng số 10)

Với cách trên nếu xảy lỗi chúng ta sẽ khó biết được lỗi xảy ra ở câu lệnh nào, nên chúng ta có thể thiết lập 1 cờ để kết hợp với IF... ESLE/CASE để việc xử lý được tường minh hơn.

Code tham khảo

DECLARE @is_error BIT = 0;
DECLARE @ma_nv NVARCHAR(9) = '77777';
SET XACT_ABORT ON
BEGIN TRAN
BEGIN TRY
	INSERT INTO NHANVIEN ( [HONV] ,[TENLOT] ,[TENNV] ,[MANV] ,[NGSINH] ,[DCHI] ,[PHAI] ,[LUONG] ,[MA_NQL] ,[PHG] )
					VALUES ('Van', 'Cong',  'Khanh',  @ma_nv, '2000/10/10','Binh Duong','Nam',30000,'005', 5)
	-- SELECT * FROM NHANVIEN WHERE MANV = @ma_nv
END TRY

BEGIN CATCH
	SET @is_error = 1;
END CATCH

IF @is_error = 0
	BEGIN
		BEGIN TRY
			INSERT INTO THANNHAN ([MA_NVIEN] ,[TENTN],[PHAI],[NGSINH] ,[QUANHE]	)
					VALUES (@ma_nv, 'Nhan Nhan', 'Nam','2000/10/10','ban be')
			PRINT 'Them THANH CONG'
		END TRY
		BEGIN CATCH
			ROLLBACK TRAN
			PRINT 'Them vao bang (THANNHAN) THAT BAI'
		END CATCH
	END
ELSE
BEGIN
	PRINT 'Them vao bang (NHANVIEN) THAT BAI'
END;

• Viết chương trình thêm một công việc mới cho đề án số 1, đồng thời phân công nhân viên mới thêm ở câu trên đảm nhận công việc mới tạo.

Chúng tôi thực với cú pháp đơn để các bạn dễ hiểu, các bạn có thể kết với RAISEERROR kết hợp với các mã lỗi (tham khảo ở phần 2 )

DECLARE 
	@ma_dean INT = 1
	,@so_tt INT = 12,
	@ma_nv NVARCHAR(9) = '111';
SET XACT_ABORT ON
BEGIN TRAN
BEGIN TRY
	
	INSERT INTO CONGVIEC (MADA, STT, TEN_CONG_VIEC) VALUES (@ma_dean, @so_tt, 'Tin Hoc Van Phong')
	INSERT INTO PHANCONG (MA_NVIEN, MADA, STT, THOIGIAN) VALUES (@ma_nv, @ma_dean, @so_tt,20)

	COMMIT TRAN
	PRINT 'Them THANH CONG'
END TRY
BEGIN CATCH
	ROLLBACK TRAN
	PRINT 'Them THAT BAI'
END CATCH

Tham khảo thêm tại đây

Xong!

[Database-Tự Học SQL] COM2034_SQL Server - Lab 4: Điều Kiện & Vòng Lặp - P2

Ôn lại lý thuyết:

WHILE: Vòng lặp WHILE là việc chạy/thực thi lặp đi lặp lại một đoạn CODE khi điều kiện cụ thể cho trước trả về giá trị là TRUE thì sẽ dừng. Đầu tiên, nó kiểm tra điều kiện và thực hiện một khối câu lệnh nếu điều kiện là đúng.

BREAK: 

• Dùng để thoát khỏi vòng lặp (BREAK không có bất kỳ đối số nào đi kèm)
• Nếu có nhiều WHILE lồng nhau thì BREAK sẽ thoát vòng lặp WHILE gần nó nhất

CONTINUE:

• Bỏ qua khối lệnh sau nó (khối lệnh trong bước lặp hiện tại), và thực hiện bước lặp tiếp theo
• CONTINUE không có bất kỳ đối số nào đi kèm

Cấu trúc lệnh WHILE

NỘI DUNG: Tìm về vòng lặp WHILE, TRY ... CATCH, RAISERROR

Bài 1:

Dùng vòng WHILE để viết chương trình đơn giản theo yêu cầu:

• Viết chương trình tính tổng các số chẵn từ 1 tới 10.
• Viết chương trình tính tổng các số chẵn từ 1 tới 10 nhưng bỏ số 4.

Bài 2:

Sử dụng cơ sở dữ liệu QLDA. Thực hiện các câu truy vấn sau, sử dụng vòng lặp

• Cho biết thông tin nhân viên (HONV, TENLOT, TENNV) có MaNV là số chẵn.
• Cho biết thông tin nhân viên (HONV, TENLOT, TENNV) có MaNV là số chẵn nhưng không tính nhân viên có MaNV là 4.

Bài 3:

Quản lý lỗi chương trình 

Thực hiện chèn thêm một dòng dữ liệu vào bảng PhongBan theo 2 bước 

• Nhận thông báo “Thêm dữ liệu thành công” từ khối Try
• Chèn sai kiểu dữ liệu cột MaPHG để nhận thông báo lỗi “Thêm dữ liệu thất bại” từ khối Catch

Viết chương trình khai báo biến @chia, thực hiện phép chia @chia cho số 0 và dùng RAISERROR để thông báo lỗi.

THỰC HIỆN:

Bài 1:

Dùng vòng WHILE để viết chương trình đơn giản theo yêu cầu:

• Viết chương trình tính tổng các số chẵn từ 1 tới 10.

-- Viết chương trình tính tổng các số chẵn từ 1 tới 10
DECLARE @tong INT = 0;
DECLARE @i INT = 1;

WHILE (@i <= 10)
BEGIN
	IF(@i % 2 = 0)
		SET @tong = @tong + @i
	SET @i = @i + 1
END
PRINT @tong

/*
Kết quả là 30 vì:
2
2 + 4 = 6
6 + 6 = 12
12 + 8 = 20
20 + 10 = 30
*/

• Viết chương trình tính tổng các số chẵn từ 1 tới 10, nếu số chẵn là số 8 thì kết thúc chương trình

Cách 1:

--  Viết chương trình tính tổng các số chẵn từ 1 tới 10, nếu số chẵn là số 8 thì kết thúc chương trình
DECLARE @tong_break INT = 0;
DECLARE @k INT = 1;

WHILE (@k <= 10)
BEGIN
	IF @k = 8
		BREAK

	IF(@k % 2 = 0)
		SET @tong_break = @tong_break + @k
	SET @k = @k + 1
END
PRINT @tong_break

/*
Kết quả là 12 vì:
2
2 + 4 = 6
6 + 6 = 12

Khi k = 8 thì BREAK có nghĩa sẽ kết thúc vòng lặp (vòng lặp gần nó nhất)

*/

Cách 2:

DECLARE @tong_break INT = 0;
DECLARE @k INT = 1;

WHILE (@k <= 10)
BEGIN
	

	IF(@k % 2 = 0)
		IF @k = 8
			BREAK
		ELSE
			SET @tong_break = @tong_break + @k
	SET @k = @k + 1
END
PRINT @tong_break
  

Các bạn đưa ra nhận xét gì về 2 cách trên

• Viết chương trình tính tổng các số chẵn từ 1 tới 10 nhưng bỏ số 4.

-- Viết chương trình tính tổng các số chẵn từ 1 tới 10 nhưng bỏ số 4.
DECLARE @tong_bo4 INT = 0;
DECLARE @j INT = 1;

WHILE (@j <= 10)
BEGIN
	IF @j = 4 
		BEGIN
			SET @j = @j + 1 -- phải tăng lên đếm lên 1, nếu không sẽ bị lặp vô hạng do biến đếm j = 4 hoài -> lặp tô tận 
			CONTINUE;
		END
	
	IF  (@j % 2= 0)
		SET @tong_bo4= @tong_bo4 + @j
	
	SET @j = @j + 1
END
PRINT @tong_bo4

/*
Kết quả là 26 vì:
Cách hoạt động cũng tương tự như tính tổng, tuy nhiên khi @j = 4, nó tăng lên 1 đơn vị và KHÔNG thực hiện phép cộng với giá trị = 4 này

*/

Bài 2:

Sử dụng cơ sở dữ liệu QLDA. Thực hiện các câu truy vấn sau, sử dụng vòng lặp

Cho biết thông tin nhân viên (HONV, TENLOT, TENNV) có MaNV là số chẵn.

Lấy thông tin và sắp xếp MANV theo thứ tự giảm dần

-- Lấy thông tin và sắp xếp MANV theo thứ tự giảm dần
SELECT MANV 
FROM NHANVIEN
ORDER BY MANV DESC;

Để đảm bảo MANV là INT thì chúng ta nên ép kiểu MANV sang INT, và lấy ra MANV cao nhất

-- Để đảm bảo MANV là INT thì chúng ta nên ép kiểu MANV sang INT, và lấy ra MANV cao nhất
SELECT TOP 1 
	CONVERT(INT, MANV)
FROM NHANVIEN
ORDER BY CONVERT(INT, MANV) DESC

Lấy MANV cao nhất gán vào biến @max_manv, và MANV nhấp nhất gán vào biến @min_manv (1)

-- Lấy MANV cao nhất gán vào biến @max_manv
DECLARE @max_manv INT
SET @max_manv = (SELECT TOP 1 
					CONVERT(INT, MANV)
				FROM NHANVIEN
				ORDER BY CONVERT(INT, MANV) DESC
				)

-- Tương tự lấy MANV nhấp nhất gán vào biến @min_manv
DECLARE @min_manv INT
SET @min_manv = (SELECT TOP 1 
					CONVERT(INT, MANV)
				FROM NHANVIEN
				ORDER BY CONVERT(INT, MANV) ASC
				)
-- HOẶC
DECLARE @min int = (select min(CAST(manv as int)) from NHANVIEN);
DECLARE @max int = (select max(CAST(manv as int)) from NHANVIEN);

Thực hiện theo yêu cầu (phải kết hợp với (1) để chạy nhé các bạn)

-- Thực hiện theo yêu cầu
WHILE (@min_manv < @max_manv)
BEGIN
	IF (@min_manv % 2 = 0)
		BEGIN
			SELECT MANV
				, HONV, TENLOT, TENNV
			FROM NHANVIEN
			WHERE CONVERT(INT, MANV) = @min_manv
		END
	SET @min_manv = @min_manv + 1
END

Noted 1: Với kiểu thực hiện vòng lặp như code trên chương trình chạy có nhiều khi xuất ra các dòng trắng vì MANV không tồn tại trong trường hợp MANV không liên tục,... 

Để khắc phục lỗi đó chúng ta có thể kiểm tra xem @min_manv có tồn trong bảng NHANVIEN thì mới thực hiện

-- Để khắc phục lỗi đó chúng ta có thể kiểm tra xem @min_manv có tồn trong bảng NHANVIEN thì mới thực hiện
WHILE (@min_manv < @max_manv)
BEGIN
	IF (@min_manv % 2 = 0)
		BEGIN
			IF EXISTS(SELECT CONVERT(INT, MANV) FROM NHANVIEN WHERE CONVERT(INT, MANV) = @min_manv) -- kiểm tra sự tồn tại của @min_manv trong bảng NHANVIEN
				SELECT MANV
					, HONV, TENLOT, TENNV
				FROM NHANVIEN
				WHERE (CONVERT(INT, MANV) = @min_manv)
		END
	SET @min_manv = @min_manv + 1
END;

Noted 2: Hai số chẵn kế nhau cách nhau 2 đơn vị, nếu chúng ta đã xác định được số đầu tiên rồi để tìm số chẵn tiếp theo thì chúng ta lấy số đó cộng thêm 2. => Với code trên các bạn xem và thay đổi sao cho hợp lý nhất để chương trình không cần kiểm tra các @min_manv là số lẻ. Như vậy lúc này vòng lặp chúng ta sẽ thực hiện lặp ít hơn,... mà vẫn cho ra kết quả không đổi.

Tham khảo cách KHÔNG DÙNG vòng lặp:

khong dung vong lap
SELECT MANV, TENLOT, TENNV 
FROM NHANVIEN
WHERE CONVERT(INT,MANV) %2 = 0

Cho biết thông tin nhân viên (HONV, TENLOT, TENNV) có MaNV là số chẵn nhưng không tính nhân viên có MaNV là 4.

Cách 1:

-- Cho biết thông tin nhân viên (HONV, TENLOT, TENNV) có MaNV là số chẵn nhưng không tính nhân viên có MaNV là 4
WHILE (@min_manv < @max_manv)
BEGIN
	IF (@min_manv = 4)
		BEGIN
			SET @min_manv = @min_manv + 1
			CONTINUE
		END
	IF (@min_manv % 2 = 0)
		BEGIN
			IF EXISTS(SELECT CONVERT(INT, MANV) FROM NHANVIEN WHERE CONVERT(INT, MANV) = @min_manv) -- kiểm tra sự tồn tại của @min_manv trong bảng NHANVIEN
				SELECT MANV
					, HONV, TENLOT, TENNV
				FROM NHANVIEN
				WHERE (CONVERT(INT, MANV) = @min_manv)
		END
	SET @min_manv = @min_manv + 1
END;

Cách 2:

-- HOẶC
WHILE (@min_manv < @max_manv)
BEGIN
	
	IF (@min_manv % 2 = 0)
		IF @min_manv = 4
			BEGIN
				SET @min_manv = @min_manv + 1
				CONTINUE
			END
		ELSE

			BEGIN
				IF EXISTS(SELECT CONVERT(INT, MANV) FROM NHANVIEN WHERE CONVERT(INT, MANV) = @min_manv) -- kiểm tra sự tồn tại của @min_manv trong bảng NHANVIEN
					SELECT MANV
						, HONV, TENLOT, TENNV
					FROM NHANVIEN
					WHERE (CONVERT(INT, MANV) = @min_manv)
			END
	SET @min_manv = @min_manv + 1
END;

Noted: Các bạn xem xem 2 cách trên, cách nào tối ưu hơn, vì sao

Bài 3:

Quản lý lỗi chương trình 

Thực hiện chèn thêm một dòng dữ liệu vào bảng PhongBan theo 2 bước 

• Nhận thông báo “Thêm dữ liệu thành công” từ khối Try
• Chèn sai kiểu dữ liệu cột MaPHG để nhận thông báo lỗi “Thêm dữ liệu thất bại” từ khối Catch

BEGIN TRY
	INSERT PHONGBAN ([TENPHG]
      ,[MAPHG]
      ,[TRPHG]
      ,[NG_NHANCHUC])
	VALUES ('keToan',2,'003','2020-06-02')
	 -- Nếu lệnh chèn thực thi thành công in ra dòng bên dưới
	PRINT 'SUCCESS: Them du lieu THANH CONG'
END TRY
-- Nếu có lỗi xảy ra khi chèn dữ liệu in ra dòng thông báo lỗi cùng với thông tin mã lỗi và thông báo lỗi
BEGIN CATCH
	PRINT 'FAILURE: Them du lieu THAT BAI'
	PRINT 'ERROR ' + CONVERT(varchar, ERROR_NUMBER()) 
		+ ': ' + ERROR_MESSAGE()
END CATCH

Kết quả:

Chạy lần 1 sẽ cho kết quả thành công

(1 row affected)

SUCCESS: Them du lieu THANH CONG

Completion time: 2022-05-25T10:50:40.1103666+07:00

Chạy lần 2 bị thông báo lỗi vì MAPHG đã tồn tại

(0 rows affected)

FAILURE: Them du lieu THAT BAI

ERROR 2627: Violation of PRIMARY KEY constraint 'PK_PhongBan'. Cannot insert duplicate key in object 'dbo.PHONGBAN'. The duplicate key value is (3).

Completion time: 2022-05-25T10:51:03.3769594+07:00

Viết chương trình khai báo biến @chia, thực hiện phép chia @chia cho số 0 và dùng RAISERROR để thông báo lỗi.

BEGIN TRY
	DECLARE @chia INT
	SET @chia = 55/0
END TRY
BEGIN CATCH
	DECLARE
		@ErrMessage NVARCHAR(2048), -- độ dài của chuỗi thông báo lỗi
		@ErrSeverity INT,
		@ErrState INT
		
	SELECT
		@ErrMessage = ERROR_MESSAGE(),
		@ErrSeverity = ERROR_SEVERITY(),
		@ErrState = ERROR_STATE()
		RAISERROR(@ErrMessage, @ErrSeverity, @ErrState) -- thực hiện hiển thị thông báo
END CATCH

Kết quả:

Msg 50000, Level 16, State 1, Line 15
Divide by zero error encountered.
Completion time: 2022-05-25T11:10:58.7629608+07:00

Xong!

[Database-Tự Học SQL] COM2034_SQL Server - Lab 4: Điều Kiện & Vòng Lặp - P1

NỘI DUNG:  Tìm hiểu chủ đề IF ... ELSE, IIF, CASE 

Bài 1:

• Viết câu truy vấn đếm số lượng nhân viên trong từng phòng ban, nếu số lượng nhân viên nhỏ hơn 3  thì hiển thị “Thiếu nhân viên”, ngược lại <5 hiển thị “Đủ Nhan Vien”, ngược lại hiển thị”Đông nhân viên”
• Viết câu truy vấn hiển thị TenNV và thêm cột thuế dựa vào mức lương: trong khoảng 0 and 25000 thì Thuế= LUONG*0.1, trong khoảng 25000 and 30000 thì LUONG*0.12, trong khoảng 30000 and 40000 thì LUONG *0.15, trong khoảng 40000 and 50000 thì LUONG *0.2, còn lại LUONG*0.25

Bài 2:

Sử dụng cơ sở dữ liệu QLDA. Thực hiện các câu truy vấn sau, sử dụng if…else và case

Viết chương trình xem xét có tăng lương cho nhân viên hay không. Hiển thị cột thứ 1 là TenNV, cột thứ 2 nhận giá trị

• “TangLuong” nếu lương hiện tại của nhân viên nhở hơn trung bình lương trong phòng mà nhân viên đó đang làm việc. 
• “KhongTangLuong “nếu lương hiện tại của nhân viên lớn hơn trung bình lương trong phòng mà nhân viên đó đang làm việc.

Viết chương trình phân loại nhân viên dựa vào mức lương.

• Nếu lương nhân viên nhỏ hơn trung bình lương mà nhân viên đó đang làm việc thì xếp loại “nhanvien”, ngược lại xếp loại “truongphong”

Viết chương trình hiển thị TenNV tùy vào cột phái của nhân viên, 

• nếu phái là Nữ thì ghi Ms. + TENNV, 
• Nam thì ghi Mr. + TENNV, 
• Ngược lại Khong_ro + TENNV

Viết chương trình tính thuế mà nhân viên phải đóng theo công thức:

• 0<luong<25000 thì đóng 10% tiền lương
• 25000<luong<30000 thì đóng 12% tiền lương
• 30000<luong<40000 thì đóng 15% tiền lương
• 40000<luong<50000 thì đóng 20% tiền lương
• Luong>50000 đóng 25% tiền lương

THỰC HIỆN:

Bài 1:

• Viết câu truy vấn đếm số lượng nhân viên trong từng phòng ban, nếu số lượng nhân viên nhỏ hơn 3  thì hiển thị “Thiếu nhân viên”, ngược lại <5 hiển thị “Đủ Nhan Vien”, ngược lại hiển thị”Đông nhân viên”

Đếm nhân viên theo từng phòng ban

-- thực hiện đếm nhân viên theo từng phòng ban trước
SELECT NHANVIEN.PHG
	, COUNT(NHANVIEN.MANV) AS 'So_nv'
FROM NHANVIEN
GROUP BY NHANVIEN.PHG

Dùng IFF thực hiện theo yêu cầu đề bài

SELECT NHANVIEN.PHG
	, COUNT(NHANVIEN.MANV) AS 'So_nv'
	, 'Ghi Chu' = IIF(COUNT(NHANVIEN.MANV) < 3, 'thieu -> can tuyen them',
					  IIF(COUNT(NHANVIEN.MANV) < 5, 'Du nhan vien', 'Dong nhan vien')
					 )
FROM NHANVIEN
GROUP BY NHANVIEN.PHG

Dùng CASE

--CASE
SELECT PHONGBAN.TENPHG
	, COUNT(NHANVIEN.PHG) So_luong_nhan_vien
	, Ghi_Chu = CASE 
		WHEN COUNT(NHANVIEN.PHG) < 3  THEN 'Thieu nhan vien'
		WHEN COUNT(NHANVIEN.PHG) < 5  THEN 'Du nhan vien'
	ELSE 'Dong nhan vien'
	END
FROM NHANVIEN 
	INNER JOIN PHONGBAN ON PHONGBAN.MAPHG = NHANVIEN.PHG
GROUP BY PHONGBAN.TENPHG

• Viết câu truy vấn hiển thị TenNV và thêm cột thuế dựa vào mức lương: 

- Trong khoảng 0 and 25000 thì Thuế= LUONG*0.1, 
- Trong khoảng 25000 and 30000 thì LUONG*0.12, 
- Trong khoảng 30000 and 40000 thì LUONG *0.15, 
- Trong khoảng 40000 and 50000 thì LUONG *0.2, 
- Còn lại LUONG*0.25

SELECT TENNV, LUONG, 
 THUE = CASE
			WHEN LUONG BETWEEN 0 AND 25000 THEN LUONG * 0.1
			WHEN LUONG BETWEEN 25000 AND 30000 THEN LUONG * 0.12
			WHEN LUONG BETWEEN 30000 AND 40000 THEN LUONG * 0.15
			WHEN LUONG BETWEEN 40000 AND 50000 THEN LUONG * 0.2
			ELSE LUONG * 0.25 
		END
FROM NHANVIEN

Bài 2:

Sử dụng cơ sở dữ liệu QLDA. Thực hiện các câu truy vấn sau, sử dụng if…else và case

Viết chương trình xem xét có tăng lương cho nhân viên hay không. Hiển thị cột thứ 1 là TenNV, cột thứ 2 nhận giá trị

• “TangLuong” nếu lương hiện tại của nhân viên nhở hơn trung bình lương trong phòng mà nhân viên đó đang làm việc. 
• “KhongTangLuong “nếu lương hiện tại của nhân viên lớn hơn trung bình lương trong phòng mà nhân viên đó đang làm việc.

Mức lương trung bình mỗi phòng ban

-- Mức lương trung bình mỗi phòng ban
SELECT NHANVIEN.PHG
	, AVG(NHANVIEN.LUONG)
FROM NHANVIEN
GROUP BY NHANVIEN.PHG

Lưu kết quả vào biến bảng (1)

-- Lưu kết quả vào biến bảng (1)
DECLARE @cau_1a TABLE (ma_phong INT, luong_TB FLOAT)
INSERT INTO @cau_1a
	SELECT NHANVIEN.PHG
		, AVG(NHANVIEN.LUONG)
	FROM NHANVIEN
	GROUP BY NHANVIEN.PHG

Thực hiện theo yêu cầu đề bài - Dùng IIF

-- thực hiện theo yêu cầu đề bài (phải kết nối bảng (1) với bảng nhân viên) 
-- dùng IIF

SELECT 
	NHANVIEN.TENNV
	, NHANVIEN.LUONG AS Luong_HienTai
	, Ghi_Chu_IIF = IIF (NHANVIEN.LUONG < bang_LTB.luong_TB, 'Tang luong', 'KHONG TANG luong')
FROM NHANVIEN
	INNER JOIN @cau_1a AS bang_LTB ON NHANVIEN.PHG = bang_LTB.ma_phong

Thực hiện theo yêu cầu đề bài - Dùng CASE

-- dùng CASE
SELECT 
	NHANVIEN.TENNV
	, NHANVIEN.LUONG AS Luong_HienTai
	, Ghi_Chu_CASE = CASE
		WHEN (NHANVIEN.LUONG < bang_LTB.luong_TB) THEN 'Tang luong'		
		ELSE 'KHONG TANG luong'
	END
FROM NHANVIEN
	INNER JOIN @cau_1a AS bang_LTB ON NHANVIEN.PHG = bang_LTB.ma_phong

Viết chương trình phân loại nhân viên dựa vào mức lương.

• Nếu lương nhân viên nhỏ hơn trung bình lương mà nhân viên đó đang làm việc thì xếp loại “nhanvien”, ngược lại xếp loại “truongphong”

Mức lương trung bình mỗi phòng ban

-- Mức lương trung bình mỗi phòng ban
SELECT NHANVIEN.PHG
	, AVG(NHANVIEN.LUONG)
FROM NHANVIEN
GROUP BY NHANVIEN.PHG

Lưu kết quả vào biến bảng (1)

-- Lưu kết quả vào biến bảng (1)
DECLARE @cau_1b TABLE (ma_phong INT, luong_TB FLOAT)
INSERT INTO @cau_1b
	SELECT NHANVIEN.PHG
		, AVG(NHANVIEN.LUONG)
	FROM NHANVIEN
	GROUP BY NHANVIEN.PHG

Thực hiện theo yêu cầu đề bài

-- thực hiện theo yêu cầu đề bài (phải kết nối bảng (1) với bảng nhân viên) 
SELECT 
	NHANVIEN.TENNV
	, NHANVIEN.LUONG AS Luong_HienTai
	, Ghi_Chu_IIF = IIF (NHANVIEN.LUONG < bang_LTB.luong_TB, 'Nhan Vien', 'Truong Phong')
FROM NHANVIEN
	INNER JOIN @cau_1b AS bang_LTB ON NHANVIEN.PHG = bang_LTB.ma_phong

Viết chương trình hiển thị TenNV tùy vào cột phái của nhân viên, 

• Nếu phái là Nữ thì ghi Ms. + TENNV, 
• Nam thì ghi Mr. + TENNV, 
• Ngược lại Khong_ro + TENNV

Simple CASE

-- Simple CASE 
SELECT 'Ten_nhanvien Simple CASE ' = CASE NHANVIEN.PHAI
	WHEN N'Nữ' THEN 'Ms. ' + NHANVIEN.TENNV
	WHEN N'Nam' THEN 'Mr. ' + NHANVIEN.TENNV
	ELSE 'Khong_ro ' + NHANVIEN.TENNV
	END
FROM NHANVIEN

Searched CASE

-- Searched CASE
SELECT 'ten nv' = CASE 
	WHEN NHANVIEN.PHAI LIKE N'Nữ' THEN 'Ms. ' + NHANVIEN.TENNV
	WHEN NHANVIEN.PHAI LIKE N'Nam' THEN 'Mr. ' + NHANVIEN.TENNV
	ELSE 'Khong_ro ' + NHANVIEN.TENNV
	END
FROM NHANVIEN

Viết chương trình tính thuế mà nhân viên phải đóng theo công thức:

• 0<luong<25000 thì đóng 10% tiền lương
• 25000<luong<30000 thì đóng 12% tiền lương
• 30000<luong<40000 thì đóng 15% tiền lương
• 40000<luong<50000 thì đóng 20% tiền lương
• Luong>50000 đóng 25% tiền lương

Thực hiện yêu cầu (Searched Case)

SELECT
	NHANVIEN.TENNV
	,NHANVIEN.LUONG
	,'Dong Thue' = CASE
			WHEN NHANVIEN.LUONG between 0 and 25000 THen NHANVIEN.LUONG * 0.1
			WHEN NHANVIEN.LUONG between 25000 and 30000 THen NHANVIEN.LUONG * 0.12
			WHEN NHANVIEN.LUONG between 30000 and 40000 THen NHANVIEN.LUONG * 0.15
			WHEN NHANVIEN.LUONG between 40000 and 50000 THen NHANVIEN.LUONG * 0.20
			ELSE NHANVIEN.LUONG * 0.25
	END
FROM NHANVIEN

Noted: Câu hỏi đặt ra ở câu lệnh trên là nếu mức lương 25000 thì thuế sẽ đóng là 10% hay 12% ? => Máy tính sẽ thực hiện từ trên xuống nếu lương 25000 thỏa mản điều kiện đầu nên thuế sẽ đóng là 10% (Thứ tự các câu lệnh trong trường hợp này các bạn cần để ý)

Xong!

[Database-Tự Học SQL] COM2034_SQL Server - Lab 3: Các Hàm Hệ Thống & Xử Lý Chuỗi

NỘI DUNG: 

Bài 1:

Với mỗi đề án, liệt kê tên đề án và tổng số giờ làm việc một tuần của tất cả các nhân viên tham dự đề án đó. 

• Xuất định dạng “tổng số giờ làm việc” kiểu decimal với 2 số thập phân.
• Xuất định dạng “tổng số giờ làm việc” kiểu varchar

Với mỗi phòng ban, liệt kê tên phòng ban và lương trung bình của những nhân viên làm việc cho phòng ban đó.

• Xuất định dạng “luong trung bình” kiểu decimal với 2 số thập phân, sử dụng dấu phẩy để phân biệt phần nguyên và phần thập phân.
• Xuất định dạng “luong trung bình” kiểu varchar. Sử dụng dấu phẩy tách cứ mỗi 3 chữ số trong chuỗi ra, gợi ý dùng thêm các hàm Right, Replace

Bài 2: 

Sử dụng các hàm toán học

Với mỗi đề án, liệt kê tên đề án và tổng số giờ làm việc một tuần của tất cả các nhân viên tham dự đề án đó.

• Xuất định dạng “tổng số giờ làm việc” với hàm CEILING
• Xuất định dạng “tổng số giờ làm việc” với hàm FLOOR
• Xuất định dạng “tổng số giờ làm việc” làm tròn tới 2 chữ số thập phân

Cho biết họ tên nhân viên (HONV, TENLOT, TENNV) có mức lương trên mức lương trung bình (làm tròn đến 2 số thập phân) của phòng "Nghiên cứu"

Bài 3:

Sử dụng các hàm xử lý chuỗi

Danh sách những nhân viên (HONV, TENLOT, TENNV, DCHI) có trên 2 thân nhân, thỏa các yêu cầu

• Dữ liệu cột HONV được viết in hoa toàn bộ
• Dữ liệu cột TENLOT được viết chữ thường toàn bộ
• Dữ liệu chột TENNV có ký tự thứ 2 được viết in hoa, các ký tự còn lại viết thường (ví dụ: kHanh)
• Dữ liệu cột DCHI chỉ hiển thị phần tên đường, không hiển thị các thông tin khác như số nhà hay thành phố.

Cho biết tên phòng ban và họ tên trưởng phòng của phòng ban có đông nhân viên nhất, hiển thị thêm một cột thay thế tên trưởng phòng bằng tên “Fpoly”

Bài 4:

Sử dụng các hàm ngày tháng năm

• Cho biết các nhân viên có năm sinh trong khoảng 1960 đến 1965.
• Cho biết tuổi của các nhân viên tính đến thời điểm hiện tại.
• Dựa vào dữ liệu NGSINH, cho biết nhân viên sinh vào thứ mấy.
• Cho biết số lượng nhân viên, tên trưởng phòng, ngày nhận chức trưởng phòng và ngày nhận chức trưởng phòng hiển thi theo định dạng dd-mm-yy (ví dụ 25-04-2019)

Bài 5:  

Cho biết các nhân viên nhỏ tuổi nhất có tham gia dự án

Cho biết khoảng cách giữa lương cao nhất và lương thấp nhất là bao nhiêu. Thông tin hiển thị gồm: LuongCaoNhat, LuongThapNhat, ChenhLech. Định dạng lương theo mẫu (#,##0 triệu đồng).

 Hiển thị danh sách nhân viên gồm các thông tin: Mã nhân viên, họ và tên, Năm sinh, Độ tuổi

Được xét dựa trên tuổi: 

- Tuổi >50 : Cao tuổi

- Tuổi từ 25 – 50: Trung bình

- Tuổi <25: Nhỏ tuổi

THỰC HIỆN:

Bài 1:

Với mỗi đề án, liệt kê tên đề án và tổng số giờ làm việc một tuần của tất cả các nhân viên tham dự đề án đó. 

SELECT 
	DEAN.TENDEAN
	,SUM ( PHANCONG.THOIGIAN) AS 'Tong_thoi_gian'
FROM DEAN
	INNER JOIN CONGVIEC ON DEAN.MADA = CONGVIEC.MADA
	INNER JOIN PHANCONG ON CONGVIEC.MADA = PHANCONG.MADA
GROUP BY DEAN.TENDEAN

Xuất định dạng “tổng số giờ làm việc” kiểu decimal với 2 số thập phân.

Xuất định dạng “tổng số giờ làm việc” kiểu varchar

SELECT 
	DEAN.TENDEAN
	,SUM ( PHANCONG.THOIGIAN) AS 'Tong_thoi_gian'
	,CAST(SUM ( PHANCONG.THOIGIAN) AS DECIMAL (10,2)) AS 'Tong_thoi_gian_CAST_DEC_2_ThapPhan'
	,CONVERT( DECIMAL (10,2), SUM ( PHANCONG.THOIGIAN)) AS 'Tong_thoi_gian_CONVERT_DEC_2_ThapPhan'
FROM DEAN
	INNER JOIN CONGVIEC ON DEAN.MADA = CONGVIEC.MADA
	INNER JOIN PHANCONG ON CONGVIEC.MADA = PHANCONG.MADA
GROUP BY DEAN.TENDEAN

Với mỗi phòng ban, liệt kê tên phòng ban và lương trung bình của những nhân viên làm việc cho phòng ban đó.

SELECT PHONGBAN.TENPHG, 
	AVG(NHANVIEN.LUONG)
FROM PHONGBAN
	INNER JOIN NHANVIEN ON PHONGBAN.MAPHG = NHANVIEN.PHG
GROUP BY PHONGBAN.TENPHG

Xuất định dạng “luong trung bình” kiểu decimal với 2 số thập phân, sử dụng dấu phẩy để phân biệt phần nguyên và phần thập phân.

SELECT PHONGBAN.TENPHG, 
	CONVERT(DECIMAL(20,2),AVG(NHANVIEN.LUONG)) AS Decimal_2_ThapPhan,
	REPLACE(CONVERT(DECIMAL(20,2),AVG(NHANVIEN.LUONG)),'.',',') AS Decimal_2_ThapPhan_thay_CHAM_thanh_PHAY
FROM PHONGBAN
	INNER JOIN NHANVIEN ON PHONGBAN.MAPHG = NHANVIEN.PHG
GROUP BY PHONGBAN.TENPHG

Xuất định dạng “luong trung bình” kiểu varchar. Sử dụng dấu phẩy tách cứ mỗi 3 chữ số trong chuỗi ra, gợi ý dùng thêm các hàm Right, Replace

SELECT PHONGBAN.TENPHG, 
	CONVERT(VARCHAR,AVG(NHANVIEN.LUONG)) AS Kieu_Varchar,
	REPLACE(CONVERT(VARCHAR,AVG(NHANVIEN.LUONG)), /* chuyển lương trung bình sang VARCHAR */
			RIGHT(CONVERT(VARCHAR(10),AVG(NHANVIEN.LUONG)),3), /* Tìm chuỗi */
			',' + RIGHT(CONVERT(VARCHAR(10),AVG(NHANVIEN.LUONG)),3) ) /* Thay thế bằng chuỗi mới */
			AS Tach_nhom_3_chu_so
FROM PHONGBAN
	INNER JOIN NHANVIEN ON PHONGBAN.MAPHG = NHANVIEN.PHG
GROUP BY PHONGBAN.TENPHG

Noted: Yêu cầu chủ yếu để các bạn thực hành và hiểu về các sử dụng các hàm đã học. Các bạn cũng có thể sử dụng hàm FORMAT trong trường hợp này.

SELECT PHONGBAN.TENPHG
	,FORMAT(AVG(NHANVIEN.LUONG), '#,###.#0')
FROM PHONGBAN
	INNER JOIN NHANVIEN ON PHONGBAN.MAPHG = NHANVIEN.PHG
GROUP BY PHONGBAN.TENPHG

Ngoài ra hàm FORMAT cũng có thể dùng để định dạng ngày tháng năm. Ví dụ: FORMAT (GETDATE(), 'dd/mm/yyy hh:mm:ss') 

Các bạn có thể tìm hiểu hàm FORMAT tại đây

Bài 2: 

SỬ DỤNG CÁC HÀM TOÁN HỌC

Với mỗi đề án, liệt kê tên đề án và tổng số giờ làm việc một tuần của tất cả các nhân viên tham dự đề án đó.

SELECT DEAN.TENDEAN, 
	SUM(THOIGIAN) 
FROM DEAN
	INNER JOIN CONGVIEC ON dean.MADA = CONGVIEC.MADA
	INNER JOIN PHANCONG ON CONGVIEC.MADA = PHANCONG.MADA
GROUP BY DEAN.TENDEAN

Xuất định dạng “tổng số giờ làm việc” với hàm CEILING

Xuất định dạng “tổng số giờ làm việc” với hàm FLOOR

Xuất định dạng “tổng số giờ làm việc” làm tròn tới 2 chữ số thập phân

SELECT DEAN.TENDEAN, 
	CEILING(SUM(THOIGIAN)) AS Ham_CEILING,
	FLOOR(SUM(THOIGIAN)) AS Ham_FLOOR,
	ROUND(SUM(THOIGIAN),2) AS Ham_ROUND_2_So_ThapPhan
FROM DEAN
	INNER JOIN CONGVIEC ON dean.MADA = CONGVIEC.MADA
	INNER JOIN PHANCONG ON CONGVIEC.MADA = PHANCONG.MADA
GROUP BY DEAN.TENDEAN

Cho biết họ tên nhân viên (HONV, TENLOT, TENNV) có mức lương trên mức lương trung bình (làm tròn đến 2 số thập phân) của phòng "Nghiên cứu"

Chuẩn bị truy vấn

-- chuẩn bị 
SELECT HONV, TENLOT, TENNV
	, LUONG
FROM NHANVIEN
WHERE LUONG > (SELECT AVG(LUONG) FROM NHANVIEN AS nvien, PHONGBAN AS pban
				WHERE nvien.PHG = pban.MAPHG and TENPHG = N'Nghiên cứu')

Dùng hàm ROUND để thực hiện yêu cầu

SELECT HONV, TENLOT, TENNV
	, ROUND(LUONG,2)
FROM NHANVIEN
WHERE LUONG > (SELECT AVG(LUONG) FROM NHANVIEN AS nvien, PHONGBAN AS pban
				WHERE nvien.PHG = pban.MAPHG and TENPHG = N'Nghiên cứu')

Bài 3: 

SỬ DỤNG CÁC HÀM XỬ LÝ CHUỖI

Danh sách những nhân viên (HONV, TENLOT, TENNV, DCHI) có trên 2 thân nhân, thỏa các yêu cầu (1)

-- chuẩn bị
SELECT THANNHAN.MA_NVIEN
	,HONV
	,TENLOT
	,TENNV
	,DCHI
	,COUNT(THANNHAN.MA_NVIEN)
FROM THANNHAN
	INNER JOIN NHANVIEN ON THANNHAN.MA_NVIEN = NHANVIEN.MANV
GROUP BY THANNHAN.MA_NVIEN,HONV, TENLOT, TENNV, DCHI
HAVING COUNT(THANNHAN.MA_NVIEN) > 2

Dữ liệu cột HONV được viết in hoa toàn bộ

Dữ liệu cột TENLOT được viết chữ thường toàn bộ

Dữ liệu chột TENNV có ký tự thứ 2 được viết in hoa, các ký tự còn lại viết thường (ví dụ: kHanh)

SELECT THANNHAN.MA_NVIEN
	, UPPER ( HONV)
	, LOWER(TENLOT)
	, LEFT(LOWER(TENNV),1) + UPPER (SUBSTRING(LOWER(TENNV), 2,1)) + RIGHT(LOWER(TENNV), LEN(LOWER(TENNV))-2)
	, NHANVIEN.DCHI 
	,COUNT(THANNHAN.MA_NVIEN)
FROM THANNHAN
INNER JOIN NHANVIEN ON THANNHAN.MA_NVIEN = NHANVIEN.MANV
GROUP BY THANNHAN.MA_NVIEN,HONV, TENLOT, TENNV, DCHI
HAVING COUNT(THANNHAN.MA_NVIEN) > 2

Dữ liệu cột DCHI chỉ hiển thị phần tên đường, không hiển thị các thông tin khác như số nhà hay thành phố.

Chúng ta sẽ dùng hàm substring trong trường hợp này, chạy với truy đơn giản trước (2)

SELECT DCHI
,SUBSTRING(DCHI,
		CHARINDEX(' ', DCHI) +1, 
		 /*chiều dài của địa chỉ, TRỪ vị trí khoảng trắng đầu tiên, TRỪ cho vị trị trí của dấu phẩy sau khi đảo ngược địa chỉ */
		LEN(DCHI) - CHARINDEX(' ', DCHI) - CHARINDEX(',', REVERSE( DCHI))) AS DIACHI
FROM  NHANVIEN

Hoặc

SELECT SUBSTRING (NHANVIEN.DCHI,
					CHARINDEX(' ',NHANVIEN.DCHI ) + 1, -- căn cứ vào khoảng trắng đầu tiên để xác định vị trí bắt đầu lấy
					CHARINDEX(',',NHANVIEN.DCHI)-1 - CHARINDEX(' ',NHANVIEN.DCHI )) -- xác định vị trí dấu phẩy, sau đó trừ đi vị trí khoảng trắng đầu tiên
FROM NHANVIEN

Thay vào câu (2) vào (1)

SELECT THANNHAN.MA_NVIEN
	,HONV
	,TENLOT
	,TENNV
	,SUBSTRING (NHANVIEN.DCHI,
				CHARINDEX(' ',NHANVIEN.DCHI ) + 1, 
				CHARINDEX(',',NHANVIEN.DCHI)-1 - CHARINDEX(' ',NHANVIEN.DCHI )) 
	,COUNT(THANNHAN.MA_NVIEN)
FROM THANNHAN
	INNER JOIN NHANVIEN ON THANNHAN.MA_NVIEN = NHANVIEN.MANV
GROUP BY THANNHAN.MA_NVIEN,HONV, TENLOT, TENNV, DCHI
HAVING COUNT(THANNHAN.MA_NVIEN) > 2

Cho biết tên phòng ban và họ tên trưởng phòng của phòng ban có đông nhân viên nhất, hiển thị thêm một cột thay thế tên trưởng phòng bằng tên “Fpoly”

Lấy ra phòng có số nhân viên đông nhất (chưa có tên trưởng phòng)

-- lấy phòng có số nhân viên đông nhất
SELECT TOP 1
	NHANVIEN.PHG
	, PHONGBAN.TENPHG
	, PHONGBAN.TRPHG
	, COUNT(NHANVIEN.MANV) AS so_nhanvien
FROM NHANVIEN
	INNER JOIN PHONGBAN ON NHANVIEN.PHG = PHONGBAN.MAPHG
GROUP BY NHANVIEN.PHG, PHONGBAN.TENPHG, PHONGBAN.TRPHG
ORDER BY so_nhanvien DESC

Hiển thị thêm tên trưởng phòng

-- PHONGBAN.TRPHG là mã số nhân viên, ngoài ra bảng nhân viên (manv) và bảng phòng ban (trphg) còn có quan hệ khác 
SELECT TOP 1
	NHANVIEN.PHG
	, PHONGBAN.TENPHG
	, PHONGBAN.TRPHG
	, nhan_vien2.TENNV
	, COUNT(NHANVIEN.MANV) AS so_nhanvien
FROM NHANVIEN
	INNER JOIN PHONGBAN ON NHANVIEN.PHG = PHONGBAN.MAPHG
	INNER JOIN NHANVIEN AS nhan_vien2 ON nhan_vien2.MANV = PHONGBAN.TRPHG
GROUP BY NHANVIEN.PHG, PHONGBAN.TENPHG, PHONGBAN.TRPHG, nhan_vien2.TENNV
ORDER BY so_nhanvien DESC

Thực hiện theo yêu cầu đề bài

-- Thực hiện thay thế theo yêu cầu
SELECT TOP 1
	NHANVIEN.PHG
	, PHONGBAN.TENPHG
	, PHONGBAN.TRPHG
    , nhan_vien2.TENNV
	, REPLACE( nhan_vien2.TENNV,  nhan_vien2.TENNV, 'Fpoly') AS Thay_the_ten_TruongPhong
	, COUNT(NHANVIEN.MANV) AS so_nhanvien
FROM NHANVIEN
	INNER JOIN PHONGBAN ON NHANVIEN.PHG = PHONGBAN.MAPHG
	INNER JOIN NHANVIEN AS nhan_vien2 ON nhan_vien2.MANV = PHONGBAN.TRPHG
GROUP BY NHANVIEN.PHG, PHONGBAN.TENPHG, PHONGBAN.TRPHG, nhan_vien2.TENNV
ORDER BY so_nhanvien DESC

Bài 4: 

SỬ DỤNG CÁC HÀM NGÀY THÁNG NĂM

Cho biết các nhân viên có năm sinh trong khoảng 1960 đến 1965.

SELECT NHANVIEN.MANV
	, NHANVIEN.TENNV
	, DATENAME(year, NHANVIEN.NGSINH) 
FROM NHANVIEN
WHERE 
	YEAR(NHANVIEN.NGSINH) BETWEEN 1960 AND 1965

Cho biết tuổi của các nhân viên tính đến thời điểm hiện tại.

SELECT 
	MANV, TenNV, YEAR(GETDATE()) - YEAR(NGSINH) as 'Tuoi'
FROM NHANVIEN;

Dựa vào dữ liệu NGSINH, cho biết nhân viên sinh vào thứ mấy.

SELECT NHANVIEN.MANV
	, NHANVIEN.TENNV
	, DATENAME(WEEKDAY, NHANVIEN.NGSINH) 
FROM NHANVIEN

Cho biết số lượng nhân viên, tên trưởng phòng, ngày nhận chức trưởng phòng và ngày nhận chức trưởng phòng hiển thi theo định dạng dd-mm-yy (ví dụ 25-04-2019)

Ban đầu chúng ta chỉ hiển thị mã trưởng phòng

-- Hiển thị mã trưởng phòng, dùng để nháp và lập luận
SELECT COUNT(NHANVIEN.MANV)
	, PHONGBAN.TRPHG
	, CONVERT(VARCHAR,NG_NHANCHUC,105)
FROM NHANVIEN
	INNER JOIN PHONGBAN ON NHANVIEN.PHG = PHONGBAN.MAPHG 
GROUP BY PHONGBAN.TRPHG, CONVERT(VARCHAR,NG_NHANCHUC,105)

Noted: Vì trưởng phòng cũng là một nhân viên, nên chúng ta có thể biết được tên nhân viên nhờ mã trưởng phòng (mã nhân viên) trong bảng NHANVIEN. 

SELECT COUNT(NHANVIEN.MANV)
	,PHONGBAN.TRPHG
	,nhan_vien2.TENNV
	, CONVERT(VARCHAR,NG_NHANCHUC,105)
FROM NHANVIEN
	INNER JOIN PHONGBAN ON NHANVIEN.PHG = PHONGBAN.MAPHG
	INNER JOIN NHANVIEN AS nhan_vien2 ON nhan_vien2.MANV = PHONGBAN.TRPHG 
GROUP BY PHONGBAN.TRPHG, nhan_vien2.TENNV, CONVERT(VARCHAR,NG_NHANCHUC,105)

Bài 5:  

Cho biết các nhân viên nhỏ tuổi nhất có tham gia dự án

Cho biết khoảng cách giữa lương cao nhất và lương thấp nhất là bao nhiêu. Thông tin hiển thị gồm: LuongCaoNhat, LuongThapNhat, ChenhLech. Định dạng lương theo mẫu (#,##0 triệu đồng).

 Hiển thị danh sách nhân viên gồm các thông tin: Mã nhân viên, họ và tên, Năm sinh, Độ tuổi

Được xét dựa trên tuổi: 

- Tuổi >50 : Cao tuổi

- Tuổi từ 25 – 50: Trung bình

- Tuổi <25: Nhỏ tuổi

??

Xong!

[Database-Tự Học SQL] COM2034_SQL Server - Lab 2: Sử Dụng Biến

NỘI DUNG

A. Chương trình tính diện tích, chu vi hình chữ nhật khi biết chiều dài và chiều rộng.

B. Dựa trên csdl QLDA thực hiện truy vấn, các giá trị truyền vào và trả ra phải dưới dạng sử dụng biến.

1. Cho biêt nhân viên có lương cao nhất
2. Cho biết họ tên nhân viên (HONV, TENLOT, TENNV) có mức lương trên mức lương trung bình của phòng "Nghiên cứu”
3. Với các phòng ban có mức lương trung bình trên 30,000, liệt kê tên phòng ban và số lượng nhân viên của phòng ban đó.
4. Với mỗi phòng ban, cho biết tên phòng ban và số lượng đề án mà phòng ban đó chủ trì

THỰC HIỆN

A. Chương trình tính diện tích, chu vi hình chữ nhật khi biết chiều dài và chiều rộng.

/*
Chu vi (C) = (dai + rong ) * 2
Dien tich (S) = dai * rong
*/

DECLARE @dai INT, @rong INT, @chu_vi INT, @dien_tich INT
SET @dai = 30
SET @rong = 20
SET @chu_vi = (@dai + @rong	) * 2
SET @dien_tich = @dai * @rong

PRINT @chu_vi
PRINT @dien_tich

-- hoặc
PRINT 'Chu vi: ' + CONVERT(CHAR(10),@chu_vi)
PRINT 'Dien tich: ' + CONVERT(CHAR(10),@dien_tich)

-- hoặc
SELECT @chu_vi AS Chu_vi, @dien_tich AS Dien_tich

Biến dùng để lưu trữ các giá trị tạm thời trong quá trình thực thi chương trình

B. Dựa trên csdl QLDA thực hiện truy vấn, các giá trị truyền vào và trả ra phải dưới dạng sử dụng biến.

1. Cho biêt nhân viên có lương cao nhất

-- chuẩn bị
SELECT  MAX(luong) FROM NHANVIEN 

SELECT * 
FROM NHANVIEN 
WHERE 
	LUONG = (SELECT  MAX(luong) FROM NHANVIEN )

-- dùng biến
DECLARE @max_luong INT
SET @max_luong = (SELECT  MAX(luong) FROM NHANVIEN)
                    
SELECT * 
FROM NHANVIEN 
WHERE 
	LUONG = @max_luong

2. Cho biết họ tên nhân viên (HONV, TENLOT, TENNV) có mức lương trên mức lương trung bình của phòng "Nghiên cứu”

-- chuẩn bị
SELECT  AVG(luong) 
FROM NHANVIEN, PHONGBAN 
WHERE 
		PHONGBAN.MAPHG = NHANVIEN.PHG 
	AND PHONGBAN.TENPHG LIKE N'Nghiên cứu' /* (1) */

SELECT CONCAT(HONV,' ', TENLOT,' ', TENNV) AS Ho_va_Ten 
FROM NHANVIEN 
WHERE 
	LUONG > /* (1) */ (SELECT  AVG(luong) 
				FROM NHANVIEN, PHONGBAN 
				WHERE 
						PHONGBAN.MAPHG = NHANVIEN.PHG 
					AND PHONGBAN.TENPHG LIKE N'Nghiên cứu')

-- dùng biến
DECLARE @avg_luong INT
/* gán (1) vào biến @avg_luong */
SET @avg_luong = (SELECT  AVG(luong) 
					FROM NHANVIEN, PHONGBAN 
					WHERE 
							PHONGBAN.MAPHG = NHANVIEN.PHG 
						AND PHONGBAN.TENPHG LIKE N'Nghiên cứu' /* (1) */
					)
SELECT CONCAT(HONV,' ', TENLOT,' ', TENNV) AS Ho_va_Ten, LUONG FROM NHANVIEN WHERE LUONG > @avg_luong

-- HOẶC, nói chung có nhiều cách giải nhá các bạn, chủ yếu là biết cách dùng biến thế nào, tạm thời chúng ta không xét phần data type trong chủ đề này
BEGIN
	DECLARE @avg_luong INT;
	
	SELECT @avg_luong = AVG(luong) FROM PHONGBAN 
	INNER JOIN NHANVIEN on PHONGBAN.MAPHG = NHANVIEN.PHG
	WHERE PHONGBAN.TENPHG = N'Nghiên cứu';
    SELECT * FROM NHANVIEN WHERE luong > @avg_luong;
	-- SELECT CONCAT(honv, tenlot) AS 'Họ Tên Lót', luong FROM NHANVIEN WHERE luong > @avg_luong;

-- có thể dùng thêm biến bảng
DECLARE @ket_qua TABLE (honv NVARCHAR(20), tenlot NVARCHAR(20), luong FLOAT);
	INSERT INTO @ket_qua
	SELECT HONV,TENLOT,LUONG FROM NHANVIEN WHERE luong > @avg_luong;

	SELECT CONCAT(honv, tenlot) AS 'Họ Tên Lót', luong FROM @ket_qua;

END;

-- hoặc

DECLARE @NGHIENCUU INT
SET @NGHIENCUU = (SELECT  PHONGBAN.MAPHG FROM PHONGBAN WHERE PHONGBAN.TENPHG = N'NGHIÊN CỨU')

-- SELECT * FROM  NHANVIEN WHERE NHANVIEN.PHG = 5;
-- SELECT AVG(NHANVIEN.LUONG) FROM  NHANVIEN WHERE NHANVIEN.PHG = @NGHIENCUU;

DECLARE @LUONGTB  FLOAT;

SET @LUONGTB = (SELECT AVG(NHANVIEN.LUONG) FROM  NHANVIEN WHERE NHANVIEN.PHG = @NGHIENCUU)

-- SELECT @LUONGTB

SELECT CONCAT(NHANVIEN.HONV, ' ', NHANVIEN.TENLOT, ' ', NHANVIEN.TENNV) AS [Họ và tên], LUONG as [Lương] FROM NHANVIEN WHERE LUONG > @LUONGTB

3. Với các phòng ban có mức lương trung bình trên 30,000, liệt kê tên phòng ban và số lượng nhân viên của phòng ban đó.

-- chuẩn bị
SELECT PHONGBAN.TENPHG, COUNT(NHANVIEN.MANV) FROM PHONGBAN,NHANVIEN 
WHERE PHONGBAN.MAPHG = NHANVIEN.PHG  
GROUP BY PHONGBAN.TENPHG

SELECT PHONGBAN.TENPHG, COUNT(NHANVIEN.MANV), AVG(Luong)  FROM PHONGBAN,NHANVIEN 
WHERE (PHONGBAN.MAPHG = NHANVIEN.PHG)  
GROUP BY PHONGBAN.TENPHG 
HAVING AVG(Luong) > 31000

-- dùng biến bảng
DECLARE @cau3 TABLE (ten_pb NVARCHAR(20), so_luong INT, avg_luong INT)

INSERT INTO @cau3
SELECT PHONGBAN.TENPHG, COUNT(NHANVIEN.MANV), AVG(Luong)  FROM PHONGBAN,NHANVIEN 
WHERE (PHONGBAN.MAPHG = NHANVIEN.PHG)  
GROUP BY PHONGBAN.TENPHG 
HAVING AVG(Luong) > 31000

SELECT * FROM @cau3

4. Với mỗi phòng ban, cho biết tên phòng ban và số lượng đề án mà phòng ban đó chủ trì

-- chuẩn bị bảng
SELECT * FROM DEAN

SELECT COUNT(mada) FROM DEAN GROUP BY phong

SELECT phongban.TENPHG, COUNT(mada) FROM DEAN, PHONGBAN WHERE DEAN.PHONG = PHONGBAN.MAPHG GROUP BY phongban.TENPHG

-- dùng biến
DECLARE @cau4 TABLE (ten_pb NVARCHAR(20), so_dean INT)
INSERT INTO @cau4
SELECT phongban.TENPHG, COUNT(mada) FROM DEAN, PHONGBAN WHERE DEAN.PHONG = PHONGBAN.MAPHG GROUP BY phongban.TENPHG

SELECT * FROM @cau4

Tham khảo bài subquery/truy vấn con/truy vấn lồng tại đây

Xong!

[Database-Tự Học SQL] Backup SQL Server - Script To Backup All SQL Server Databases - T-SQL

NỘI DUNG:

1. Thực hiện trên Microsoft SQL Server Management Studio

• Tạo đường dẫn để lưu các file backup  (1)
• Định nghĩa tên file  (2)
• Trích lọc chọn các database cần backup  (3)
• Thực hiện vòng lặp để duyệt hết list các database (3) cần backup
• Tạo script backup với các thông tin từ (1), (2), (3)
• Thực hiện backup test

2. Thực hiện trên SQL Server Configuration Manager

• Enable TCP/IP và gán port sẽ sử dụng cho SQL Server
• Restart SQL Server Service

3. Thực hiện trên Windows

• Allow inbound rules trên Windows Firewall và kiểm tra
• Tạo file script kết hợp SQL command line lưu với tên file OSQL_call_bk_SQL.bat
• Tạo file script tìm xóa chỉ giữ lại các file trong 3 ngày gần nhất  và lưu lại với tên forfile_del.bat
• Tạo file script có tên schedule_cmd.bat call và thực thi OSQL_call_bk_SQL.bat và forfile_del.bat
• Khởi tạo lập lịch back up định kỳ.

THỰC HIỆN

1. Thực hiện trên Microsoft SQL Server Management Studio

• Tạo đường dẫn để lưu các file backup
• Định nghĩa tên file 
• Trích lọc chọn các database cần backup
• Thực hiện vòng lặp để duyệt hết list các database (mục 3) cần backup
• Tạo script backup với các thông tin từ mục 1, mục 2, mục 3
• Thực hiện backup test

CODE:

Tạo file bk_QSL.sql

DECLARE @name NVARCHAR(256) -- ten database 
DECLARE @path NVARCHAR(512) -- duong dan de luu backup files  
DECLARE @fileName NVARCHAR(512) -- ten file backup  
DECLARE @fileDate NVARCHAR(40) -- lay ngay gio he thong luu vao bien nay ket hop voi fileName
 
-- (1) cai dat duong dan, ban phai dam bao folder dang ton tai
SET @path = 'C:\SQL_backups\BAKs' 
 
-- thuc hien lay ngay gio he thong luu vao bien
SELECT @fileDate = (SELECT FORMAT (getdate(), 'yyyymmdd_hhmmss'))
 
DECLARE db_cursor CURSOR READ_ONLY FOR  
SELECT [name] -- (3) thuc hien trich loc file can backup
FROM master.sys.databases 
WHERE name NOT IN ('master','model','msdb','tempdb')  -- khong lay cac database he thong
AND state = 0 -- cac database online
AND is_in_standby = 0 -- database is not read only for log shipping
AND [name] not like 'ReportServer%' -- databases he thong (tuy version ma 'ReportServer...' co database nay hay khong)

OPEN db_cursor   
FETCH NEXT FROM db_cursor INTO @name   
 
WHILE @@FETCH_STATUS = 0   -- lap duyet qua tat ca database
BEGIN   
   SET @fileName = @path + '\' + @fileDate + '_' + @name + '.BAK'  -- (2) ten file gom: duong dan + ngay gio + ten cua database
   BACKUP DATABASE @name TO DISK = @fileName  -- thuc hien backup FULL
   -- WITH DIFFERENTIAL -- co the thuc hien backup thay doi
   
	RESTORE VERIFYONLY -- kiem tra xem back up thanh cong hay khong, co doc duoc hay khong
	FROM DISK = @fileName
	

   FETCH NEXT FROM db_cursor INTO @name   
END   
 
CLOSE db_cursor   
DEALLOCATE db_cursor

Tùy nhu cầu, chúng ta có thể backup log với cấu trúc lệnh

BACKUP LOG [ten_database]
TO DISK = 'C:\SQL_backups\tenfile_canluu.trn'
GO

Hoặc tham khảo thêm các lựa chọn khác tại đây 

Noted: Ghi chú tiếng việt có dấu trong phần code T-SQL sẽ bị lỗi khi sử dụng lệnh osql nên chúng tôi ghi chú tiếng việt không dấu

CHẠY THỬ:

Processed 496 pages for database 'QLDA', file 'QLDA' on file 1.

Processed 1 pages for database 'QLDA', file 'QLDA_log' on file 1.

BACKUP DATABASE successfully processed 497 pages in 0.068 seconds (57.006 MB/sec).

Processed 432 pages for database 'QL_NhaTro', file 'QL_NhaTro' on file 1.

Processed 1 pages for database 'QL_NhaTro', file 'QL_NhaTro_log' on file 1.

BACKUP DATABASE successfully processed 433 pages in 0.061 seconds (55.351 MB/sec).

Processed 400 pages for database 'QLDA_COM2034', file 'QLDA' on file 1.

Processed 2 pages for database 'QLDA_COM2034', file 'QLDA_log' on file 1.

BACKUP DATABASE successfully processed 402 pages in 0.194 seconds (16.168 MB/sec).

Completion time: 2022-05-11T16:34:49.5008303+07:00

KẾT QUẢ:

2. Thực hiện trên SQL Server Configuration Manager

• Enable TCP/IP và gán port sẽ sử dụng cho SQL Server: Đảm bảo TCP/IP đã Enable, và thiết lập port cho SQL Server (ở đây chúng tôi dùng port 1433)

- SQL Server Configuration Manager -> Protocols for SQL...-> TCP/IP -> Enable

- SQL Server Configuration Manager -> Protocols for SQL...-> TCP/IP -> Properties -> Tab IP Addresses -> IPAll -> TCPPort điền 1433 -> OK

• Restart SQL Server Service: Khởi động lại SQL Server

Mở SQL Server Configuration Manager -> SQL Server Services -> SQL Server -> Restart

3. Thực hiện trên Windows

• Allow inbound rules trên Windows Firewall và kiểm tra

    Mở cmd run as Administrator

netsh advfirewall firewall add rule name="Allow TCP Port 1433" dir=in action=allow protocol=TCP localport=1433

Ngoài ra chúng ta cũng có thể thêm port vào Windows Firewall bằng giao diện có thể tham khảo ở link này (mục 1.3)

    Kiểm tra port đã lắng nghe trên máy chưa (Listening là đã lắng nghe)

netstat -ano | find "1433"

    Kết quả:

Có thể kiểm tra thêm bằng phần mềm tcping cho chắc ăn (đảm bảo các máy khác cũng có thể truy cập được SQL với port 1433)

tcping -h localhost 1433

    Kết quả: Nếu 1433 is Open -> ổn

Noted: có thể thay localhost bằng IP hoặc tên máy tính của các bạn


Download phần mềm TCPING tại đây

• Tạo file script kết hợp SQL command line lưu với tên file OSQL_call_bk_SQL.bat

Tạo file có tên OSQL_call_bk_SQL.bat

@echo off
set _DateTime=%date%%time%
set _DateTime=%_DateTime: =_%
set _DateTime=%_DateTime::=-%
set _DateTime=%_DateTime:/=-%
set _DateTime=%_DateTime:.=_%

set _srcScript="C:\SQL_backups\Script\bk_SQL.sql"
set _dstLogs="c:\SQL_Backups\Logs"

if NOT EXIST %_dstLogs% MD %_dstLogs%

::osql -E -S "localhost" -i "C:\SQL_backups\Script\bk_SQL.sql" 

osql -E -S "localhost" -i %_srcScript% -o "%_dstLogs%\%_DateTime%.txt"

@echo on

Noted: Tùy theo từng version mà sql command có thể là: iSQL, oSQL, SQLcmd,...... Đường dẫn đến file thường là (150 màu đỏ là tùy theo version mà chúng ta chọn cho hợp lý) C:\Program Files\Microsoft SQL Server\150\Tools\Binn

Tham khảo cách lấy ngày giờ hệ thống trên command tại link

• Tạo file script tìm xóa chỉ giữ lại các file trong 3 ngày gần nhất  và lưu lại với tên forfile_del.bat (tùy theo nhu cầu thực tế)

@echo off
set _DateTime=%date%%time%
set _DateTime=%_DateTime: =_%
set _DateTime=%_DateTime::=-%
set _DateTime=%_DateTime:/=-%
set _DateTime=%_DateTime:.=_%

set _path=C:\SQL_backups
set _dirfile=BAKs
set _logs=Logs

set _days=3
forfiles /p "%_path%\%_dirfile%" /s /m *.BAK /D -%_days% /C "cmd /c del /q @path&echo @path >>%_path%\%_logs%\%_DateTime%_DelFileList.txt"

@echo on 

Tham khảo tìm và xóa file với Forfiles tại link

• Tạo file script có tên schedule_cmd.bat call và thực thi OSQL_call_bk_SQL.bat và forfile_del.bat 

call C:\SQL_backups\Script\OSQL_call_bk_SQL.bat
call C:\SQL_backups\Script\forfile_del.bat

Noted: Các bạn đảm bảo rằng trong đĩa C:\ (đây là Lab nên chúng tôi lưu như vậy) có các folder và file như hình dưới:

• C:\SQL_backups\Logs: là nơi lưu trữ file log khi backup SQL và các file đã xóa file của lệnh forfiles
• C:\SQL_backups\BAKs: chứa các file .bak là định dạng file backup của SQL
• C:\SQL_backups\Script: chứa các file script

Các bạn có thể gọi thêm các script khác tùy theo nhu cầu, ví dụ: sau khi backup xong nén file log lại gửi đến email cho các bạn.

• Khởi tạo lập lịch back up định kỳ.

Task Schedule -> Create Basic Task... -> đặt tên -> Next -> Daily (Tùy các bạn chọn) -> Next

Cài đặt thời gian chạy file backup -> Next -> Start a program -> Next

Chọn đường dẫn đến nơi chứa file cần thực thi -> Next -> Finish

Kiểm tra lại Task Schedule vừa tạo

Kết quả thực thi

Link tham khảo

Xong!